ループ内のエントリを読み取ってXSLを使用して重複したエントリを削除する

Question

私はXSLを初めて使用していますが、xmlタグのデータを読み込んでそれを配列などに格納してから、明確なオプションを使用してください。

例えば、

<local> 
    <ID> 
    <fruit>apple</fruit> 
    <fruit>orange</fruit> 
    </ID> 
    <ID> 
    <fruit>apple</fruit> 
    <fruit>mango</fruit> 
    </ID> 
</local> 

これでは、私はループのイニシエータとしてローカルを読んでおり、その下のすべてのIDを読み込んで果物を表示する必要があります。この場合、4つの異なるフルーツがあり、1つは複製されていないので、それらのユニークなエントリを表示したいだけです。 XSLTを使ってこれを行う可能性はありますか？

<xsl:for-each select="Local"> 
    <xsl:variable name="fruits"> 
    <xsl:for-each select="set:distinct(ID/fruit)"> 
     <xsl:copy-of select="."/> 
    </xsl:for-each> 
    </xsl:variable> 
</xsl:for-each> 

Answer 1

I.このXSLT 1.0変換：

：

<local> 
    <ID> 
     <fruit>apple</fruit> 
     <fruit>orange</fruit> 
    </ID> 
    <ID> 
     <fruit>apple</fruit> 
     <fruit>mango</fruit> 
    </ID> 
</local> 

が望む正しい結果を生成する：提供されるXML文書に塗布

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 
<xsl:output omit-xml-declaration="yes" indent="yes"/> 
<xsl:strip-space elements="*"/> 

<xsl:key name="kFruitByName" match="fruit" use="."/> 

<xsl:template match="/"> 
    <xsl:copy-of select= 
    "/*/*/fruit 
    [generate-id() 
    = 
     generate-id(key('kFruitByName', .)[1]) 
    ]"/> 
</xsl:template> 
</xsl:stylesheet> 

<fruit>apple</fruit> <fruit>orange</fruit> <fruit>mango</fruit> 

説明：Muenchian method for groupingを使用します。

---

II。 XSLT 2.0のソリューション：

<xsl:stylesheet version="2.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 
<xsl:output omit-xml-declaration="yes" indent="yes"/> 

<xsl:template match="/*"> 
    <xsl:for-each-group select="*/fruit" group-by="."> 
    <xsl:sequence select="."/> 
    </xsl:for-each-group> 
</xsl:template> 
</xsl:stylesheet> 

この変換は、（上記）と同じXML文書に適用されたときに、再び同じ正しい結果が生成されます

<fruit>apple</fruit> 
<fruit>orange</fruit> 
<fruit>mango</fruit>