MS Accessのアプリケーションアイコンのパス

Question

MS Access 2003のアプリケーションアイコンのパスにプログラムでどのようにアクセスしますか？

Answer 1

データベースオブジェクトのカスタムプロパティ（「AppIcon」）です。

Set dbs = CurrentDb 
sAppIconPath = dbs.Properties("AppIcon") 

注 - プロパティが存在しない場合は、エラーが発生します。

例

次の例は、Microsoft Accessデータベース（.mdb）にAPPICONとAppTitleのプロパティを変更する方法を示しています。

Accessのヘルプからこのコードは、プロパティを作成する方法を示しています。プロパティがまだ設定または作成されていない場合は、それらを作成し、CreatePropertyメソッドを使用してPropertiesコレクションに追加する必要があります。

Sub cmdAddProp_Click() 
    Dim intX As Integer 
    Const DB_Text As Long = 10 
    intX = AddAppProperty("AppTitle", DB_Text, "My Custom Application") 
    intX = AddAppProperty("AppIcon", DB_Text, "C:\Windows\Cars.bmp") 
    CurrentDb.Properties("UseAppIconForFrmRpt") = 1 
    Application.RefreshTitleBar 
End Sub 

Function AddAppProperty(strName As String, _ 
     varType As Variant, varValue As Variant) As Integer 
    Dim dbs As Object, prp As Variant 
    Const conPropNotFoundError = 3270 

    Set dbs = CurrentDb 
    On Error GoTo AddProp_Err 
    dbs.Properties(strName) = varValue 
    AddAppProperty = True 

AddProp_Bye: 
    Exit Function 

AddProp_Err: 
    If Err = conPropNotFoundError Then 
     Set prp = dbs.CreateProperty(strName, varType, varValue) 
     dbs.Properties.Append prp 
     Resume 
    Else 
     AddAppProperty = False 
     Resume AddProp_Bye 
    End If 
End Function