Delphi onshowメインフォーム/モーダルフォーム

Question

私はメインフォームと他のフォームを持つプロジェクトを持っています。 アプリが読み込まれると、いくつかのタスクを実行し、結果をモーダルフォームでメインフォームの上部に表示する必要があります。 問題は、タスク/作成を行う関数を呼び出すと、メインフォームonshowイベントでモーダルフォームを表示すると、モーダルフォームが表示されますが、モーダルフォームが閉じられるまでメインフォームは表示されません。私は何が起こると思いますか。これに対処するために、メインフォームにタイマーを追加し、メインフォームのonshowイベントでタイマーを起動します。タイマーは、タスクを実行する関数を呼び出します/モーダルフォームを作成して表示します。これでモーダルフォームの前にメインフォームが表示されます。

しかし、私はこれが最善の解決策であるとは見えず、誰かがより良いものを提供できるかどうか疑問に思っていました。私は、Delphi 7

コリンを使用しています

Answer 1

1つの一般的に使用さオプションは、自分自身のフォームのOnShowでメッセージを投稿することです。このように：

const 
    WM_SHOWMYOTHERFORM = WM_USER + 0; 

type 
    TMyMainForm = class(TForm) 
    procedure FormShow(Sender: TObject); 
    protected 
    procedure WMShowMyOtherForm(var Message: TMessage); message WM_SHOWMYOTHERFORM; 
    end; 

... 


procedure TMyMainForm.FormShow(Sender: TObject); 
begin 
    PostMessage(Handle, WM_SHOWMYOTHERFORM, 0, 0); 
end; 

procedure TMyMainForm.WMShowMyOtherForm(var Message: TMessage); 
begin 
    inherited; 
    with TMyOtherForm.Create(nil) do begin 
    try 
     ShowModal; 
    finally 
     Free; 
    end; 
    end; 
end; 

Answer 2

なぜあなたがそうのようなMainForm OnActivateイベントを使用していけませんか？

procedure TMyMainForm.FormActivate(Sender: TObject); 
begin 
    //Only execute this event once ... 
    OnActivate := nil; 

    //and then using the code David Heffernan offered ... 
    with TMyOtherForm.Create(nil) do begin 
    try 
     ShowModal; 
    finally 
     Free; 
    end; 
end; 

イベントをnilに設定すると、起動時にこのコードが1回だけ実行されます。

Answer 3

Windows API関数ShowWindowの呼び出しが行われる直前に、OnShowイベントが発生します。 ShowWindowへのこの呼び出しが実際に画面に表示されます。

ShowWindowの呼び出しの直後に実行する必要があるのが理想です。このすべてを駆動するVCLコードは、CM_SHOWINGCHANGEDのメッセージハンドラTCustomFormの内部にあることが判明しました。そのメッセージハンドラはOnShowイベントを発生させ、ShowWindowを呼び出します。したがって、優れた解決策は、CM_SHOWINGCHANGEDのハンドラが実行された直後にモーダルフォームを表示することです。このように：

type 
    TMyMainForm = class(TForm) 
    private 
    FMyOtherFormHasBeenShown: Boolean; 
    protected 
    procedure CMShowingChanged(var Message: TMessage); message CM_SHOWINGCHANGED; 
    end; 

..... 

procedure TMyMainForm.CMShowingChanged(var Message: TMessage); 
begin 
    inherited; 
    if Showing and not FMyOtherFormHasBeenShown then begin 
    FMyOtherFormHasBeenShown := True; 
    with TMyOtherForm.Create(nil) do begin 
     try 
     ShowModal; 
     finally 
     Free; 
     end; 
    end; 
    end; 
end;