テーブルからストアドプロシージャに整数値の配列を渡す方法は？

Question

私は、渡された値に基づいていくつかの列を更新する動的SQLを使用するストアドプロシージャを持っています。私は手動でそれらを入力することなく複数の値のためにそれをテストしようとしています。これらの値は表から取られる。これらの値をすべてテーブルに渡してprocを通過させる方法はありますか？通常のプログラミング言語のように、配列を実行します。私は2012年

コードは、私は別の値を持つテーブルからその整数パラメータ（@enteredvalue）の値を入力します。この

CREATE PROCEDURE sp1 @enteredvalue int 
AS 
BEGIN 
    UPDATE table1 
    SET column1 = 'some var char value', 
     column2 = 'some integer values' 
    WHERE xid = @enteredvalue 
END 

のようなものであるSQL Serverの中でこれをやっています。

Answer 1

必要であれば、おそらく、もう少しダイナミックSQLは、（パーサと一緒に）トリック

Declare @String varchar(max) = '1,25,659' 
Declare @SQL varchar(max) = '' 
Select @SQL = @SQL + concat('Exec [dbo].[sp1] ',Key_Value,';',char(13)) 
From (Select * from [dbo].[udf-Str-Parse-8K](@String,',')) A 

Select @SQL 
--Exec(@SQL) 

戻り

Exec [dbo].[sp1] 1; 
Exec [dbo].[sp1] 25; 
Exec [dbo].[sp1] 659; 

UDFを行います（超高速！）

CREATE FUNCTION [dbo].[udf-Str-Parse-8K](@String varchar(8000), @Delimiter varchar(50)) 
Returns Table 
As 

--Usage: Select * from [dbo].[udf-Str-Parse-8K]('Dog,Cat,House,Car',',') 
--  Select * from [dbo].[udf-Str-Parse-8K]('John||Cappelletti||was||here','||') 
--  Select * from [dbo].[udf-Str-Parse-8K]('The quick brown fox',' ') 

Return (
    with cte1(N) As (Select 1 From (Values(1),(1),(1),(1),(1),(1),(1),(1),(1),(1)) N(N)), 
     cte2(N) As (Select Top (IsNull(DataLength(@String),0)) Row_Number() over (Order By (Select NULL)) From (Select N=1 From cte1 a, cte1 b, cte1 c, cte1 d) A), 
     cte3(N) As (Select 1 Union All Select t.N+DataLength(@Delimiter) From cte2 t Where Substring(@String,t.N,DataLength(@Delimiter)) = @Delimiter), 
     cte4(N,L) As (Select S.N,IsNull(NullIf(CharIndex(@Delimiter,@String,s.N),0)-S.N,8000) From cte3 S) 

    Select Key_PS = Row_Number() over (Order By A.N) 
     ,Key_Value = Substring(@String, A.N, A.L) 
     ,Key_Pos = A.N 
    From cte4 A 
) 

Answer 2

もう1つのアプローチは、（動的SQLを使用せずに）

入力パラメータは、その手順でテーブル https://msdn.microsoft.com/en-us/library/bb510489.aspx

2）である

1）各列を通過し、各個々の行値の

例えば、既存のSPを実行するために作成し、WHILEループを新しいSPを作成しますループがここにいる間に：

SQL Call Stored Procedure for each Row without using a cursor

Answer 3

SPにテーブルを渡すには、ユーザー定義テーブル型を作成することを検討。例：

create type ArrayOfInt as table (IntVal int) 
go 


create proc SumArray(@IntArray ArrayOfInt readonly) 
as 
select sum(IntVal) from @IntArray 
go 

declare @IntArray ArrayOfInt 

insert @IntArray values (1), (2), (3) 

select * from @IntArray 

exec SumArray @IntArray 

drop proc SumArray 

drop type ArrayOfInt