デルファイ：円形のユニット参照を避けるためのデザインが改善されましたか？

Question

私はDelphi 10で三角形のメッシュ構造を持っています。

パフォーマンスの理由から、メッシュの頂点、三角形の面などのデータをTListの子孫に格納します。

TListsにリストのすべてのメンバーの計算をさせます。これらの計算では、TMesh構造のいくつかのフィールドにアクセスする必要があります。したがって、TMeshの作成とそれに続くリストの作成中に、リストに親のTMeshを割り当てます。私はそうするためにTMeshの前方宣言を使用します。次のコードを参照してください：

type 
    {forward declaration} 
    TMesh=class; 

    TVertex=record 
    Point: TPoint3D; 
    //other fields 
    end; 

    TVertices=class(TList<TVertex>) 
    Mesh: TMesh; 
    procedure DoSomethingWithAllVertices; //uses some fields of TMesh 
    constructor Create(const AMesh: TMesh); 
    //other methods 
    end; 

    TTriangleFace=record 
    Vertices: Array[0..2] of Integer; 
    //other fields 
    end; 

    TTriangleFaces=class(TList<TTriangleFace>) 
    Mesh: TMesh; 
    procedure DoSomethingWithAllTriangleFaces; //uses some fields of TMesh 
    constructor Create(const AMesh: TMesh); 
    //other methods 
    end; 

    TMesh=class(TComponent) 
    Vertices: TVertices; 
    TriangleFaces: TTriangleFaces; 
    constructor Create(AOwner: TComponent); 
    //other fields & methods 
    end; 

implementation 

constructor TMesh.Create(AOwner: TComponent); 
begin 
    inherited; 
    Vertices:=TVertices.Create(Self); 
    TriangleFaces:=TTriangleFaces.Create(Self); 
end; 

constructor TVertices.Create(const AMesh: TMesh); 
begin 
    Mesh:=AMesh; 
end; 

これは問題なく動作します。

私のプロジェクトが成長して以来、ますますコードが増えています。リストクラスを別々のユニットに分けて配布したいと思います。これは、循環ユニット参照の問題をもたらす。

循環ユニット参照の問題は、かなりよく知られているようです。私は可能な解決策を確認したが、私の問題に見合うものは見つけられなかった。あなたが円形の単位の参照に遭遇すると、そのコードはあまり設計されていないと言う人もいます。

デザインを改善すると同時に、計算​​パフォーマンスを高く保つにはどうすればよいですか？

問題を解決する他の方法はありますか？

ありがとうございました！

Answer 1

あなたの現在のソリューションは、すでに問題を解決するための最良の方法です。これらのタイプを別々のユニットに分割することは、大きな障害となり、扱いにくいコードにつながります。

これらのタイプを分割したいという希望は理解できますが、結果のコードの明瞭さとその欲求とのバランスを取る必要があります。この場合、遠くに分裂するという否定的な結果は、ポジティブの重さを左右する。コードをそのまま残してください。

Answer 2

前方宣言はユニット間では機能しません。ユニットフォワードがレコード/クラスを宣言するとき、同じユニットはレコード/クラスも定義しなければなりません。

私はその後TMesh実装、および直接の代わりにTMeshのTVerticesとTTriangleFaces使用IMeshを持っていることをIMeshインタフェースを定義することをお勧め。そうすれば、循環参照はなく、インタフェースは必要なフィールド値のプロパティを公開することができます。 TComponentは、実装されたインターフェイスの参照カウントを無効にするので、メモリリークは問題になりません。

MeshIntf.pas：

unit MeshIntf; 

interface 

type 
    IMesh = interface(IInterface) 
    ['{30315BC6-9A2E-4430-96BB-297D11C9DB5D}'] 
    // methods for performing common tasks... 
    // properties for reading/setting needed values... 
    end; 

implementation 

end. 

Vertices.pas：

unit Vertices; 

interface 

uses 
    System.Types, System.Generics.Collections, MeshIntf; 

type 
    TVertex = record 
    Point: TPoint3D; 
    //other fields 
    end; 

    TVertices = class(TList<TVertex>) 
    public 
    Mesh: IMesh; 
    constructor Create(const AMesh: IMesh); reintroduce; 
    procedure DoSomethingWithAllVertices; 
    //other methods 
    end; 

implementation 

constructor TVertices.Create(const AMesh: IMesh); 
begin 
    inherited Create; 
    Mesh := AMesh; 
end; 

procedure TVertices.DoSomethingWithAllVertices; 
begin 
    // use properties/methods of Mesh as needed... 
end; 

end. 

TriangleFaces.pas：

unit TriangleFaces; 

interface 

uses 
    System.Generics.Collections, MeshIntf; 

type 
    TTriangleFace = record 
    Vertices: Array[0..2] of Integer; 
    //other fields 
    end; 

    TTriangleFaces = class(TList<TTriangleFace>) 
    public 
    Mesh: IMesh; 
    constructor Create(const AMesh: IMesh); reintroduce; 
    procedure DoSomethingWithAllTriangleFaces; 
    //other methods 
    end; 

implementation 

constructor TTriangleFaces.Create(const AMesh: IMesh); 
begin 
    inherited Create; 
    Mesh := AMesh; 
end; 

procedure TTriangleFaces.DoSomethingWithAllTriangleFaces; 
begin 
    // use properties/methods of Mesh as needed... 
end; 

end. 

Mesh.pas：

unit Mesh; 

interface 

uses 
    Classes, MeshIntf, Vertices, TriangleFaces; 

type 
    TMesh = class(TComponent, IMesh) 
    public 
    Vertices: TVertices; 
    TriangleFaces: TTriangleFaces; 
    constructor Create(AOwner: TComponent); override; 
    destructor Destroy; override; 
    //other fields & methods, and IMesh implementation 
    end; 

implementation 

constructor TMesh.Create(AOwner: TComponent); 
begin 
    inherited; 
    Vertices := TVertices.Create(Self as IMesh); 
    TriangleFaces := TTriangleFaces.Create(Self as IMesh); 
end; 

destructor TMesh.Destroy; 
begin 
    Vertices.Free; 
    TriangleFaces.Free; 
    inherited; 
end; 

end. 

TMeshをデザイン時にフォームデザイナーとオブジェクトインスペクタに使用する必要がない場合は、TComponentの代わりにTInterfacedObjectから派生させる必要があります。しかし、参照カウントを正しく処理するには、小さな調整を行う必要があります（TComponentは無効です）。特に、TVerticesとTTriangleFacesはTMeshの参照カウントをインクリメントして（その参照カウントが今までそのシナリオに0に落ちるので）メモリリークが発生しないようにを参照弱いを使用する必要があります。

MeshIntf。 PAS：

unit MeshIntf; 

interface 

uses 
    System.Types; 

type 
    TVertex = record 
    Point: TPoint3D; 
    //other fields 
    end; 

    IVertices = interface(IInterface) 
    ['{97A70A11-C8B6-4DBC-807B-B9E0C6953B9E}'] 
    // methods for performing tasks... 
    procedure DoSomethingWithAllVertices; 
    function GetVertex(Index: Integer): TVertex; 
    // properties for reading/setting values... 
    property Vertex[Index: Integer]: TVertex read GetVertex; 
    end; 

    TTriangleFace = record 
    Vertices: Array[0..2] of Integer; 
    //other fields 
    end; 

    ITriangleFaces = interface(IInterface) 
    ['{A1ED479B-7430-4524-A630-FDDE212375BB}'] 
    // methods for performing tasks... 
    procedure DoSomethingWithAllTriangleFaces; 
    function GetFace(Index: Integer): TTriangleFace; 
    // properties for reading/setting values... 
    property Face[Index: Integer]: TTriangleFace read GetFace; 
    end; 

    IMesh = interface(IInterface) 
    ['{30315BC6-9A2E-4430-96BB-297D11C9DB5D}'] 
    // methods for performing common tasks... 
    function GetVertices: IVertices; 
    function GetTriangleFaces: ITriangleFaces; 
    // properties for reading/setting values... 
    property Vertices: IVertices read GetVertices; 
    property TriangleFaces: ITriangleFaces read GetTriangleFaces; 
    end; 

implementation 

end. 

Vertices.pas：

unit Vertices; 

interface 

uses 
    System.Generics.Collections, MeshIntf; 

type 
    TVertices = class(TInterfacedObject, IVertices) 
    private 
    // Delphi 10.1 Berlin adds [weak] support to all compilers, 
    // it was previously only available on the mobile compilers... 
    {$IFDEF WEAKINTFREF} 
    [weak] fMesh: IMesh; 
    {$ELSE} 
    fMesh: Pointer; 
    {$ENDIF} 

    fVertices: TList<TVertex>; 

    public 
    constructor Create(AMesh: IMesh); 
    destructor Destroy; override; 

    //other methods 

    // IVertices implementation 
    procedure DoSomethingWithAllVertices; 
    function GetVertex(Index: Integer): TVertex; 
    end; 

implementation 

constructor TVertices.Create(AMesh: IMesh); 
begin 
    inherited Create; 
    fMesh := {$IFDEF WEAKINTFREF}AMesh{$ELSE}Pointer(AMesh){$ENDIF}; 
    fVertices := TList<TVertex>.Create; 
end; 

destructor TVertices.Destroy; 
begin 
    fVertices.Free; 
    inherited; 
end; 

procedure TVertices.DoSomethingWithAllVertices; 
begin 
    // use properties of fMesh as needed... 

    // if WEAKINTFREF is not defined simply type-cast the Mesh 
    // pointer as IMesh(fMesh) when accessing its members... 
end; 

function TVertices.GetVertex(Index: Integer): TVertex; 
begin 
    Result := fVertices[Index]; 
end; 

end. 

TriangleFaces.pas：

unit TriangleFaces; 

interface 

uses 
    System.Generics.Collections, MeshIntf; 

type 
    TTriangleFaces = class(TInterfacedObject, ITriangleFaces) 
    private 
    // Delphi 10.1 Berlin adds [weak] support to all compilers, 
    // it was previously only available on the mobile compilers... 
    {$IFDEF WEAKINTFREF} 
    [weak] fMesh: IMesh; 
    {$ELSE} 
    fMesh: Pointer; 
    {$ENDIF} 

    fFaces: TList<TTriangleFace>; 

    public 
    constructor Create(AMesh: IMesh); 
    destructor Destroy; override; 

    //other methods 

    // ITriangleFaces implementation 
    procedure DoSomethingWithAllTriangleFaces; 
    function GetFace(Index: Integer): TTriangleFace; 
    end; 

implementation 

constructor TTriangleFaces.Create(AMesh: IMesh); 
begin 
    inherited Create; 
    fMesh := {$IFDEF WEAKINTFREF}AMesh{$ELSE}Pointer(AMesh){$ENDIF}; 
    fFaces := TList<TTriangleFace>.Create; 
end; 

destructor TTriangleFaces.Destroy; 
begin 
    fFaces.Free; 
    inherited; 
end; 

procedure TTriangleFaces.DoSomethingWithAllTriangleFaces; 
begin 
    // use properties of fMesh as needed... 

    // if WEAKINTFREF is not defined simply type-cast the Mesh 
    // pointer as IMesh(fMesh) when accessing its members... 
end; 

function TTriangleFaces.GetFace(Index: Integer): TTriangleFace; 
begin 
    Result := fFaces[Index]; 
end; 

end. 

Mesh.pas：

unit Mesh; 

interface 

uses 
    MeshIntf; 

type 
    TMesh = class(TInterfacedObject, IMesh) 
    private 
    // note, these are *strong* references, not*weak* references! 
    fVertices: IVertices; 
    fTriangleFaces: ITriangleFaces; 

    public 
    constructor Create; 

    //other fields & methods 

    // IMesh implementation 
    function GetVertices: IVertices; 
    function GetTriangleFaces: ITriangleFaces; 
    end; 

implementation 

uses 
    Vertices, TriangleFaces; 

constructor TMesh.Create; 
begin 
    inherited; 
    fVertices := TVertices.Create(Self as IMesh); 
    fTriangleFaces := TTriangleFaces.Create(Self as IMesh); 
end; 

function TMesh.GetVertices: IVertices; 
begin 
    Result := fVertices; 
end; 

function TMesh.GetTriangleFaces: ITriangleFaces; 
begin 
    Result := fTriangleFaces; 
end; 

end. 

ちょうどあなたはもうそれを必要としないまで、それは生きたままのでTMeshオブジェクトを作成するときに、あなたのコード内の非弱IMesh変数のどこかにあることを確認してください：

var 
    Meth: IMesh; // or a class member or a global, wherever you need it 

Mesh := TMesh.Create; 
... 
Mesh := nil; 

（適切な）参照カウントがあなたのために残ります。