複数のデータベースをSQL Serverにドロップする方法

Question

明確にするために、実際には質問ではなく、答えを探していた私のような人にはもっと助けてください。
多くのアプリケーションで一時テーブルなどが作成されていますが、テスト用SQL ServerにTeam Foundation Serverが80以上のデータベースを作成したときに驚きました。 TFSは正しくインストールされなかったし、親切に私の後にそれをクリアするために私を残しました。各データベースは、手で各データベースを削除するのではなく、命名規則を持っていたので、私は、カーソルを使用する方法を思い出し、私が今までT-SQLの最も賢明作品であることを確認何書かれています：

CREATE TABLE #databaseNames (name varchar(100) NOT NULL, db_size varchar(50), owner varchar(50), dbid int, created date, status text, compatibility_level int); 
INSERT #databaseNames 
    exec sp_helpdb; 

DECLARE dropCur CURSOR FOR 
    SELECT name FROM #databaseNames WHERE name like '_database_name_%'; 
OPEN dropCur; 
DECLARE @dbName nvarchar(100); 
FETCH NEXT FROM dropCur INTO @dbName; 
DECLARE @statement nvarchar(200); 
WHILE @@FETCH_STATUS = 0 
BEGIN 
    SET @statement = 'DROP DATABASE ' + @dbName; 
    EXEC sp_executesql @statement; 
    FETCH NEXT FROM dropCur INTO @dbName; 
END 
CLOSE dropCur; 
DEALLOCATE dropCur; 
DROP TABLE #databaseNames; 

それはなしで行きますこのようなカーソルを使用することはおそらく本当に危険であり、非常に注意して使用すべきだと言っています。これは私にとってはうまくいっていますが、私のデータベースにはまだそれ以上のダメージはありませんでしたが、私は責任を負いません。
また、これが問題ではないので削除する必要がある場合は、わかります。ちょうど人々が見るだろうどこかにこれを投稿したかった。

Answer 1

これは簡単です...

use master 
go 
declare @dbnames nvarchar(max) 
declare @statement nvarchar(max) 
set @dbnames = '' 
set @statement = '' 
select @dbnames = @dbnames + ',[' + name + ']' from sys.databases where name like 'name.of.db%' 
if len(@dbnames) = 0 
    begin 
    print 'no databases to drop' 
    end 
else 
    begin 
    set @statement = 'drop database ' + substring(@dbnames, 2, len(@dbnames)) 
    print @statement 
    exec sp_executesql @statement 
    end 

Answer 2

代わりにこれを行うのはなぜですか。

USE master; 
Go 
SELECT 'DROP DATABASE '+ name 
FROM sys.databases WHERE name like '_database_name_%'; 
GO 

結果セットの出力をキャプチャし、別のクエリウィンドウに貼り付けます。その後、それを実行します。なぜ、このTSQLカーソルコードをすべて記述しますか？

「あなたはハンマーを持っている場合は、すべてが釘のように見えます！」..