Clojureのリストの並べ替え

Question

私はClojureリスト（またはそれが呼び出されている場合はseq）を特定の方法でソートしようとしています。最後の項目の優先順位を降順にソートし、次に最初の項目を昇順にソートします。例：

(def pnts '((1 2) 
      (2 4) 
      (3 2) 
      (4 10) 
      (5 3) 
      (6 1) 
      (7 2))) 

(sort-by last > pnts) 
;; ((4 10) (2 4) (5 3) (1 2) (3 2) (7 2) (6 1)) 
;; Notice how (1 2), (3 2), (7 2) are sorted. This 
;; is correct and is what I want. 

（ソートすることにより、最後の）ポイントは、最初は最初項目でソートされているので、これは可能かもしれないが、はトリックをやっているようです。私がポイントを書いているASCII/CLIグラフ作成スクリプトを実装する方法は、常にpntsのようになります。私の質問は、コマンドのような並べ替えの好みを保証することができますか？

PS私は（並べ替え（juxt最後に最初）（juxt> <）pnts）をやってみました。私は結果が任意の入力順のための安定していることを確認するために入力をシャッフルしている

Answer 1

私はあなたが正しいトラックにjuxtを使っていたと思います。あなたのポイントがすべて数字であると仮定すると、lastと-を構成して、最後のコンポーネントの降順自然順序をエミュレートできます。

user=> (sort-by (juxt (comp - last) first) (shuffle pnts)) 
((4 10) (2 4) (5 3) (1 2) (3 2) (7 2) (6 1)) 

Answer 2

：

(sort #(or (> (last %1) (last %2)) 
      (and (= (last %1) (last %2)) 
        (< (first %1) (first %2)))) 
     (shuffle '((1 2) (2 4) (3 2) (4 10) (5 3) (6 1) (7 2)))) 
=> ((4 10) (2 4) (5 3) (1 2) (3 2) (7 2) (6 1)) 

ここで私たちも、入力の1000年reorderingsで、検証、出力の唯一の順序があります：

(count (into #{} 
      (repeatedly 
       1000 
       (fn [] (sort #(or (> (last %1) (last %2)) 
           (and (= (last %1) (last %2)) 
            (< (first %1) (first %2)))) 
          (shuffle '((1 2) (2 4) (3 2) (4 10) (5 3) (6 1) (7 2)))))))) 
=> 1 

ここでは、シャッフルが順序の多種多様を生成することを示しています

(count (into #{} 
      (repeatedly 
       1000 
       (fn [] (shuffle '((1 2) (2 4) (3 2) (4 10) (5 3) (6 1) (7 2))))))) 
=> 899 

（シャッフルはランダム化されているので結果は変わりますが、カウントは通常850〜950の範囲内にあるようです）

Answer 3

ソートは安定しているJavaのソートを使用し、そうすることもできますちょうどソート倍

(def pnts (shuffle '((1 2) (2 4) (3 2) (4 10) (5 3) (6 1) (7 2)))) 

(->> pnts (sort-by first <) (sort-by last >)) 
;=> ((4 10) (2 4) (5 3) (1 2) (3 2) (7 2) (6 1))