VB.NET Webアプリケーション - 不要なユーザセッション共有

Question

私はPHP開発者の方がはるかに多いので、vb.netは新しくなっています。私はWebアプリケーションを構築しましたが、私のユーザーは同じセッションを共有しているように見えますが、私はそれを望んでいないし、なぜ理解できません。私はすべてのセッション情報をモジュール内のグローバルプロパティから格納するオブジェクトにアクセスします。これが理由でしょうか？次のように

コードは次のとおりです。

Module SiteWide 
    Private mUserSession As New MyLib.User.UserSession 
    Public Property gUserSession() As MyLib.User.UserSession 
     Get 
      If Not HttpContext.Current Is Nothing AndAlso Not HttpContext.Current.Session Is Nothing Then 
       If Not HttpContext.Current.Session("user") Is Nothing Then 
        mUserSession = HttpContext.Current.Session("user") 
       End If 
      End If 

      Return mUserSession 
     End Get 
     Set(ByVal value As MyLib.User.UserSession) 
      mUserSession = value 

      If Not HttpContext.Current Is Nothing AndAlso Not HttpContext.Current.Session Is Nothing Then 
       HttpContext.Current.Session("user") = value 
      End If 
     End Set 
    End Property 
End Module 

Answer 1

は、なぜあなたは、あなたのSessionオブジェクトのリポジトリとして静的クラス（モジュール）を使用していますか？静的とはアプリケーション全体を意味します。 mUserSessionも暗黙的に静的であるため、すべてのユーザーが同じセッションを共有します。実際にゲッター/セッターの行

mUserSession = value 

と

mUserSession = HttpContext.Current.Session("user") 

は、すべてのユーザーのためにそれを上書きしています。

あなただけの簡略化のために独自のクラスでSessionオブジェクトをラップすることができます。たとえば

：

Public Class MySession 
    ' private constructor 
    Private Sub New() 
    End Sub 

    ' Gets the current session. 
    Public Shared ReadOnly Property Current() As MySession 
     Get 
      Dim session As MySession = DirectCast(HttpContext.Current.Session("__MySession__"), MySession) 
      If session Is Nothing Then 
       session = New MySession() 
       HttpContext.Current.Session("__MySession__") = session 
      End If 
      Return session 
     End Get 
    End Property 

    ' **** add your session properties here, e.g like this: 
    Public Property MyID() As Guid 
     Get 
      Return m_ID 
     End Get 
     Set(value As Guid) 
      m_ID = value 
     End Set 
    End Property 
    Private m_ID As Guid 

    Public Property MyDate() As DateTime 
     Get 
      Return m_MyDate 
     End Get 
     Set(value As DateTime) 
      m_MyDate = Value 
     End Set 
    End Property 
    Private m_MyDate As DateTime 

End Class 

注：Current -propertyも/静的共有、その差はあるさ私はHttpContext.Current.Sessionを返していますが、あなたは単一の/共有インスタンスを返しています。