SQLは、開始日と終了日の間のオープンチケットを探す

Question

私は現在、次の表があります。私は、各日付に閉じられなかったIDの数を知りたいのですが

+-----+-----------------------------+------------------------------+ 
| ID |  StartDate    |  EndDate     | 
+-----+-----------------------------+------------------------------| 
| 1 | 2017-07-24 08:00:00.000 | 2017-07-29 08:00:00.000 | 
| 2 | 2017-07-25 08:00:00.000 | 2017-07-28 08:00:00.000 | 
| 3 | 2017-07-25 08:00:00.000 | 2017-07-26 08:00:00.000 | 
+-----+-----------------------------+------------------------------+ 

を。 たとえば、私は2017-07-26 00:00:00.000のオープンIDの数を知ることはできませんでした。この場合、これはすべて3になります。

もう1つの例：オープンIDの数が2017-07-29 00:00:00.000であることはわかりません。結果は1になります。 ID = 1のみがその日にまだ閉じていません。

私はここStackOverflowで別のソリューションを使用しようとしましたが、なぜ私に誤った結果を与えているのか理解できません。

declare @dt date, @dtEnd date 
set @dt = getdate()-7 
set @dtEnd = dateadd(day, 100, @dt); 

WITH CTEt1 (SupportCallID, StartDate, EndDate, Onhold) 
as 
(SELECT SupportCallID 
    ,OpenDate 
    ,MAX(CASE WHEN StatusID IN('19381771-8E81-40C5-8E36-62A7DB0A2A99', '95C7A5FB-2389-4D14-9DAE-A08BFCC3B09A', 'D5429790-3B43-4462-9E1E-2466EA29AC74') then CONVERT(DATE, LastChangeDate) end) EndDate 
    ,OnHold 
    FROM [ClienteleITSM_Prod_Application].[dbo].[SupportCall] 
    group by SupportCallID, OpenDate, OnHold 
) 



SELECT dates.myDate, 
    (SELECT COUNT(*) 
     FROM CTEt1 
    WHERE myDate BETWEEN StartDate and EndDate 
    ) 
FROM 
(select dateadd(day, number, @dt) mydate 
from 
    (select distinct number from master.dbo.spt_values 
    where name is null 
    ) n 
where dateadd(day, number, @dt) < @dtEnd) dates 

Answer 1

あなたがソース表の日付の範囲をまたがる日付のテーブルを作成するためにcteを使用する場合は、簡単にleft joinソース表と行までcountへのから返さことができます。

declare @t table(ID int,StartDate datetime,EndDate datetime); 
insert into @t values (1,'2017-07-24 08:00:00.000','2017-07-29 08:00:00.000'),(2,'2017-07-25 08:00:00.000','2017-07-28 08:00:00.000'),(3,'2017-07-25 08:00:00.000','2017-07-26 08:00:00.000'); 

declare @StartDate datetime = (select min(StartDate) from @t); 
declare @EndDate datetime = (select max(EndDate) from @t); 

    -- Table with 10 rows in to be joined together to create a large tally table (10 * 10 * 10 * etc) 
with t(t) as (select t from (values(1),(1),(1),(1),(1),(1),(1),(1),(1),(1))t(t)) 
    -- Add the row_number of the tally table to your start date to generate all dates within your data range 
    ,d(d) as (select top(datediff(d,@StartDate,@EndDate)+1) dateadd(d,row_number() over (order by (select null))-1,@StartDate) from t t1,t t2,t t3) 
select d.d 
     ,count(t.ID) as OpenIDs 
from d 
    left join @t as t 
     on(d.d between cast(t.StartDate as date) and t.EndDate) 
group by d.d 
order by d.d; 

出力：

+-------------------------+---------+ 
|   d   | OpenIDs | 
+-------------------------+---------+ 
| 2017-07-24 08:00:00.000 |  1 | 
| 2017-07-25 08:00:00.000 |  3 | 
| 2017-07-26 08:00:00.000 |  3 | 
| 2017-07-27 08:00:00.000 |  2 | 
| 2017-07-28 08:00:00.000 |  2 | 
| 2017-07-29 08:00:00.000 |  1 | 
+-------------------------+---------+