AutoCAD VBA：オブジェクトの選択

Question

私は複雑な煙突の3Dモデルを持っています。これは本質的に装飾的な特徴を持つ円筒形のチューブです。私はその長さに沿っていくつかのポイントでセクションのプロパティを見つけるVBAスクリプトを書いてみたいですが、私はそれをやる方法が本当にわかりません。オンライン検索から

、私はその後、上MASSPROPを実行することができますが、私はそれを終えることがどのように非常にわからない時点でセクションに置くコードを書くことができた...私は」だと思いますたった1行分のコードです。私はちょうど私が作成したセクションを選択する必要があります。

私の助けが必要なコードは、私のほぼ完全なコードです。

Public Sub Section() 
Dim SolidObject As Acad3DSolid 
Dim NewRegionObject As AcadRegion 
Dim PlaneOrigin As Variant 
Dim PlaneXaxisPoint As Variant 
Dim PlaneYaxisPoint As Variant 
Dim PickedPoint As Variant 
On Error Resume Next 
With ThisDrawing.Utility 
.GetEntity SolidObject, PickedPoint, vbCr & "Select solid to cut." 
If Err Then 
    MsgBox "Selected solid must be a 3DSolid" 
    Exit Sub 
End If 
PlaneOrigin = .GetPoint(PickedPoint, vbCr & "Select point to define origin.") 
PlaneXaxisPoint = .GetPoint(PickedPoint, vbCr & "Select point to define x-axis.") 
PlaneYaxisPoint = .GetPoint(PickedPoint, vbCr & "Select point to define y-axis.") 
Set NewRegionObject = SolidObject.SectionSolid(PlaneOrigin, PlaneXaxisPoint, PlaneYaxisPoint) 
End With 
ThisDrawing.SendCommand ("qaflags" & vbCr & "2" & vbCr) 'This is needed for the operation 
ThisDrawing.SendCommand ("massprop" & vbCr) 
'How do I select my NewRegionObject??? 
ThisDrawing.SendCommand (vbCr & vbCr & "y" & vbCr & vbCr & "y" & vbCr) 
End Sub 

私は、新しく作成されたセクションでMASSPROPを実行するには、このコードを取得できた場合は罰金、私は煙突に沿ったいくつかの点でプロセスを自動的に行うには、それを適応させることができるはずですので、私は1行だけだと思いますコードオフ。あなたの助けのための

おかげで、 トム

Answer 1

あなたがより良いAutoCADのオブジェクトモデルを活用したい：

Dim minPoint As Variant, maxPoint As Variant 
Set NewRegionObject = SolidObject.SectionSolid(PlaneOrigin, PlaneXaxisPoint, PlaneYaxisPoint) 
With NewRegionObject 
    MsgBox "Area: " & .Area 
    MsgBox "Perimeter: " & .Perimeter 

    .GetBoundingBox minPoint, maxPoint 
    MsgBox "Min Point coordinates: (" & minPoint(0) & "," & minPoint(1) & "," & minPoint(2) & ")" 
    MsgBox "Max Point coordinates: (" & maxPoint(0) & "," & maxPoint(1) & "," & maxPoint(2) & ")" 
    MsgBox "Centroid coordinates: (" & .Centroid(0) & "," & .Centroid(1) & ")" 
    MsgBox "Moments of Inertia: (" & .MomentOfInertia(0) & "," & .MomentOfInertia(1) & "," & .MomentOfInertia(2) & ")" 
    '.. and so on 
End With