SelectedIndexChangeを使用せずにコンボボックスがクリックされたかどうかを検出します。

Question

SelectedIndexChangeを使用しないでコンボボックスが変更されているかどうかをVB.netアプリケーションが検出できるかどうかを確認します。

私のアプリケーションには4つのコンボボックスがあり、このコンボボックスはユーザー設定から動的に作成されました。 （アプリケーション起動時にコンボボックスが自動作成されます）。その後、アプリケーションが起動されたら、それらのコンボボックスが変更されるたびにSUBを実行します。ひどく助けが必要でした。 TIA

Answer 1

コントロールを動的に作成する場合は、イベントハンドラも動的に追加する必要があります。 SelectedIndexChangedイベントの使用には何も問題ありません。

新しいプロジェクトを作成し、このコードをPublic Class Form1の中に貼り付けることでテストできます。

Private myComboBox1 As ComboBox 
Private myComboBox2 As ComboBox 

Private Shared selectedIndexChanged As EventHandler = 
    Sub(sender As Object, e As EventArgs) 
     Dim myComboBox = DirectCast(sender, ComboBox) 
     ' alert the user as to what was selected 
     MessageBox.Show(String.Format("{0} value: {1}, index: {2}", 
         myComboBox.Name, myComboBox.Text, myComboBox.SelectedIndex)) 
     ' you can do something different on each one by name in a case statement 
     Select Case myComboBox.Name 
      Case "myComboBox1" 
       ' do something for 1 
      Case "myComboBox2" 
       ' do something for 2 
     End Select 
    End Sub 

Private Sub addHandlers() 
    AddHandler myComboBox1.SelectedIndexChanged, selectedIndexChanged 
    AddHandler myComboBox2.SelectedIndexChanged, selectedIndexChanged 
End Sub 

Private Sub removeHandlers() 
    RemoveHandler myComboBox1.SelectedIndexChanged, selectedIndexChanged 
    RemoveHandler myComboBox2.SelectedIndexChanged, selectedIndexChanged 
End Sub 

フォームのEventHandler

Private Sub Form1_Load(sender As Object, e As EventArgs) Handles MyBase.Load 
    ' dynamically generate combo boxes 
    myComboBox1 = New ComboBox() With {.Name = "myComboBox1", 
             .Left = 30, 
             .Top = 30} 
    myComboBox2 = New ComboBox() With {.Name = "myComboBox2", 
             .Left = 30, 
             .Top = 60} 
    ' add some items 
    myComboBox1.Items.AddRange({1, 2, 3}) 
    myComboBox2.Items.AddRange({"four", "five", "six"}) 
    ' add the combo boxes to the form 
    Me.Controls.Add(myComboBox1) 
    Me.Controls.Add(myComboBox2) 
    ' add event handlers 
    addHandlers() 
End Sub 

Private Sub Form1_FormClosed(sender As Object, e As FormClosedEventArgs) Handles Me.FormClosed 
    removeHandlers() 
End Sub