Excel vbaで「No Cells Found Error」と表示される

Question

次のコードを使用してセルをマージ解除してコピーします。これは私が使用しているコードです。

Sub unMerge() 
    Dim lastRow As Long 
    Dim lastCol As Long 
    lastRow = Range("B2").End(xlDown).Row 
    lastCol = Range("A2").End(xlToRight).Column 

    For iCol = 1 To lastCol 

     Columns(iCol).unMerge 
     Columns(iCol).SpecialCells(xlCellTypeBlanks).FormulaR1C1 = "=r[-1]c" 

    Next iCol 
End Sub 

コードが列内のマージされたセルがあるときしかし列がマージされた細胞なしに遭遇したとき、それはキャプション付きのエラーを与えるスムーズに動作します。 コードの不具合は何でしょうか。

Answer 1

空白のセルが見つからない場合、SpecialCellsメソッドはエラーになります。これを避けるために、あなたは

そのエラーをスキップするように処理する簡単なエラーを使用することができ

On Error Resume Next 
Columns(iCol).SpecialCells(xlCellTypeBlanks).FormulaR1C1 = "=r[-1]c" 

Answer 2

他のすべてがスムーズに実行した場合、これはそれを修正するための良い方法です：

Sub unMerge() 
    Dim lastRow As Long 
    Dim lastCol As Long 
    Dim iCol As Long 

    lastRow = Range("B2").End(xlDown).Row 
    lastCol = Range("A2").End(xlToRight).Column 

    For iCol = 1 To lastCol 
     If Columns(iCol).MergeCells Then Columns(iCol).unMerge 
     If RangeContainsCellTypeBlanks(Columns(iCol)) Then 
      Columns(iCol).SpecialCells(xlCellTypeBlanks).FormulaR1C1 = "=r[-1]c" 
     End If 
    Next iCol 

End Sub 

Public Function RangeContainsCellTypeBlanks(rng As Range) As Boolean 

    On Error GoTo RangeContainsCellTypeBlanks_Error  
    If rng.Cells.SpecialCells(xlCellTypeBlanks).Count > 0 Then RangeContainsCellTypeBlanks = True 

    On Error GoTo 0 
    Exit Function  

RangeContainsCellTypeBlanks_Error:  
    RangeContainsCellTypeBlanks = False  
End Function 

それがマージされた細胞のためにとかどうかを確認しますUnMergeを実行してFormulaR1C1を書き込みます。ここでMergeCellsプロパティは、Microsoftのドキュメントです：https://msdn.microsoft.com/en-us/vba/excel-vba/articles/range-mergecells-property-excel

SpecialCellsTypeBlanksに関しては、私は本当にファンではないが、明らかにそれを中心に簡単に行くことができないので、1がOn Error Resume Nextを使用する必要がある既知の制限がありこのエラーの捕捉の - https://www.rondebruin.nl/win/s4/win003.htm

少なくとも私はブール関数でそれを使用して、残りのコードを汚染しないことを確認しています。