perlでPOST値を取得する方法

Question

私はスクリプトをカスタマイズしようとしており、perlを使用してフォームからPOST値を取得する必要があります。 私はperlの背景がありませんが、これはかなり簡単なことですので、難しくないはずです。

これは私がPerlで持ちたいコードのPHPのバージョンである：

<?php 
$download = ($_POST['dl']) ? '1' : '0'; 
?> 

私はこれがすべてでPERLバージョンに関連しないかもしれません知っているが、それは私がまさに私明確に推測助けることができますお探しですか？

Answer 1

まあ、その場合には、この単純なコードを見てください。これはあなたを助けるでしょう：

#!/usr/bin/perl 
use strict; 
use warnings; 
use CGI; 
use CGI::Carp qw(fatalsToBrowser); 

sub output_top($); 
sub output_end($); 
sub display_results($); 
sub output_form($); 

my $q = new CGI; 

print $q->header(); 

# Output stylesheet, heading etc 
output_top($q); 

if ($q->param()) { 
    # Parameters are defined, therefore the form has been submitted 
    display_results($q); 
} else { 
    # We're here for the first time, display the form 
    output_form($q); 
} 

# Output footer and end html 
output_end($q); 

exit 0; 

# Outputs the start html tag, stylesheet and heading 
sub output_top($) { 
    my ($q) = @_; 
    print $q->start_html(
     -title => 'A Questionaire', 
     -bgcolor => 'white'); 
} 

# Outputs a footer line and end html tags 
sub output_end($) { 
    my ($q) = @_; 
    print $q->div("My Web Form"); 
    print $q->end_html; 
} 

# Displays the results of the form 
sub display_results($) { 
    my ($q) = @_; 

    my $username = $q->param('user_name'); 
} 

# Outputs a web form 
sub output_form($) { 
    my ($q) = @_; 
    print $q->start_form(
     -name => 'main', 
     -method => 'POST', 
    ); 

    print $q->start_table; 
    print $q->Tr(
     $q->td('Name:'), 
     $q->td(
     $q->textfield(-name => "user_name", -size => 50) 
    ) 
    ); 

    print $q->Tr(
     $q->td($q->submit(-value => 'Submit')), 
     $q->td(' ') 
    ); 
    print $q->end_table; 
    print $q->end_form; 
} 

Answer 2

開始するには、ここをクリックしてください。The Fool's Guide to CGI.pm, the Perl module for CGI scripting

これは、「送信されたフォームからPOST値を取得して変数に割り当てる方法」を示します。

希望すると便利です。

Answer 3

スタイルのアドバイスを：あなたはほとんどの変数に0または1を割り当てる必要がありません。 boolの文脈で値そのものを評価するだけです。 body_parameters（Plack::Request (PSGI)で

#!/usr/bin/env perl 
use strict; 
use warnings FATAL => 'all'; 
use CGI qw(); 
my $c = CGI->new; 
print $c->header('text/plain'); 
if ('POST' eq $c->request_method && $c->param('dl')) { 
    # yes, parameter exists 
} else { 
    # no 
} 
print 'Do not taunt happy fun CGI.'; 

---

、あなたはPOSTのためのさまざまな方法があります：CGI.pm (CGI)で

---

、param方法は、POSTをマージし、パラメータをGETので、私たちは、別途リクエストメソッドを検査する必要があります）とGET（query_parameters）があります（parameters）。

#!/usr/bin/env plackup 
use strict; 
use warnings FATAL => 'all'; 
use Plack::Request qw(); 
my $app = sub { 
    my ($env) = @_; 
    my $req = Plack::Request->new($env); 
    if ($req->body_parameters->get_all('dl')) { 
     # yes 
    } else { 
     # no 
    } 
    return [200, [Content_Type => 'text/plain'], ['Do not taunt happy fun Plack.']]; 
}; 

Answer 4

上記の例は少し複雑です。以下のコードはPOST値を変数に読み込みます。それからキーバリューを抽出することができます。そのGETの場合は、より良いCGIモジュールを使用する。

#!/usr/bin/perl 

my $FormData = ''; 
read(STDIN, $FormData, $ENV{'CONTENT_LENGTH'}); 

## Variable $FormData holds all POST values passed 

use CGI; 
my $cgi = new CGI; 
print $cgi->header(); 
print "$FormData";