ファイルから拡張プロパティを取得

Question

私は、スクリプトが実行されたフォルダ内のビデオファイルから拡張ファイルプロパティを取得し、結果をテキストファイルに出力しようとしています。

これは、これまで私が持っているコードです：

Dim ls, fsObj, fd, fs, fl, sfs, sf, tf 

    ' specify the file extensions to list 
    dim fileTypes 
    fileTypes = Array("mp4","mkv","avi") 

On Error Resume Next 

    ls = "" 
    Set fsObj = CreateObject("Scripting.FileSystemObject") 
    Set fd = fsObj.GetFolder(".") 
Set objFolder = objShell.NameSpace(fsObj) 
    set fs = fd.Files 

For Each fileName in objFolder.Items 
    set objFolderItem = objFolder.ParseName(fileName) 
    size = objFolder.GetDetailsOf(objFolderItem, 1) 
    length = objFolder.GetDetailsOf(objFolderItem, 27) 
    height = objFolder.GetDetailsOf(objFolderItem, 283) 
    width = objFolder.GetDetailsOf(objFolderItem, 285) 
Next 


    ' list subfolders 
    set sfs = fd.SubFolders 
    For Each sf in sfs 
     ls = ls & sf.name & vbCrLf & chr(10) 
    Next 

     For Each fl in fs 
     ' check whether the extension matches 
     if arrayContains(fileTypes, fsObj.GetExtensionName(fl.name))then 
    ls = ls & fl.name & vbtab & length & vbCrLf & chr(10) 

     end if 
    Next 
    Set tf = fsObj.OpenTextFile("index.txt", 2, True, False) 

    tf.Writeline ls 

    tf.Close 
    Set fsObj = Nothing 

    function arrayContains (arr, val)    
     dim found 
     found = false 
     for i = 0 to ubound(arr) 
      if arr(i) = val then  
       found = true 
       exit for 
      end if 
     next 
     arrayContains = found    
    end function 

私は、私は他の人を追加できることを得ることができたら、ファイル名や長さを取得しようとしています。

私が推測できる限り、objFolder.ParseName（fileName）を指定する必要があります。ファイルタイプ配列に一致するすべてのファイルを指定するにはどうすればよいですか？私はfl.nameとfd.filesを試しました。私は他に何を試していいのかわかりません。

私は、二重窓にWindowsエクスプローラから7

をVBSファイルをクリックすることで、スクリプトを実行しているスクリプトがエラーなしで実行され、ファイル名を返しますが、拡張プロパティを返しません。どんな助けでも大歓迎です。

Answer 1

次のコードは、mp4ファイルの名前、サイズ、長さ、フレームの高さ、フレームの幅などの詳細を取得できます。 flv、avi、mkvの形式のファイルについては、名前とサイズのみを抽出することができます。これらのファイルの場合は、右クリックしてプロパティを選択して[詳細]タブに移動しても、長さ、高さ、幅に関する情報は表示されません。しかし、mp4の場合は、これらすべての詳細を見ることができます。エラー再開next`で

Set fso = CreateObject("scripting.filesystemobject") 
Set obs = CreateObject("shell.application") 
Set fol = fso.GetFolder(".") 
Set spl = obs.NameSpace(fol.Path) 
Set files = fol.Files 
filePath = fol.path&"\Info.txt" 
set objFile = fso.openTextFile(filePath,2,true,true) 

arr = Array("mp4", "mkv", "avi", "flv") 

For Each file In files 
    ext = fso.GetExtensionName(file.Name) 
    For Each ex In arr 
     If StrComp(ext,ex,1)=0 Then 
      objFile.writeline "NAME: "&spl.GetDetailsOf(spl.ParseName(file.Name),0)&vbcrlf&_ 
           "SIZE: "&spl.GetDetailsOf(spl.ParseName(file.Name),1)&vbcrlf&_ 
           "LENGTH: "&spl.GetDetailsOf(spl.ParseName(file.Name),27)&vbcrlf&_ 
           "FRAME HEIGHT: "&spl.GetDetailsOf(spl.ParseName(file.Name),283)&vbcrlf&_ 
           "FRAME WIDTH: "&spl.GetDetailsOf(spl.ParseName(file.Name),285)&vbcrlf&string(50,"==") 
      Exit For 
     End If 
    Next 

Next 
objFile.Close 
set objFile = Nothing 
set files = nothing 
set spl = nothing 
set fol = nothing 
set obs = nothing 
set fso = nothing