Haskellコンストラクタ型パターンマッチング

Question

私は単純な型と機能を持っていますが、そこには定型文がたくさんあるようです。私の本当の疑問は、もし入力が能力のタイプであることを知っていれば、Str/Dexのどれかのどれか、パターンマッチなしでIntegerを抽出する最も簡単な方法は何ですか？

data Ability = StrAbi Integer 
     | DexAbi Integer 
     | ConAbi Integer 
     | IntAbi Integer 
     | WisAbi Integer 
     | ChaAbi Integer 
     deriving (Show) 

data Modifier = Modifier Integer deriving (Show) 

setModifier :: Ability -> (Ability, Modifier) 
setModifier abi@(StrAbi s) = (abi, Modifier $ modifier' s) 
setModifier abi@(DexAbi s) = (abi, Modifier $ modifier' s) 
setModifier abi@(ConAbi s) = (abi, Modifier $ modifier' s) 
setModifier abi@(IntAbi s) = (abi, Modifier $ modifier' s) 
setModifier abi@(WisAbi s) = (abi, Modifier $ modifier' s) 
setModifier abi@(ChaAbi s) = (abi, Modifier $ modifier' s) 

おかげで、 //

Answer 1

あなたは、可能な各コンストラクタは同じ意味論的意味を持つフィールドを持つデータ構造を持っている通常ならば、あなたはレコード構文を使用するので、その子aを与えることができます名前：あなたは自動的にので、持っている機能abilityValue :: Ability -> Integerを構築した

data Ability = StrAbi { abilityValue ::Integer } 
     | DexAbi { abilityValue ::Integer } 
     | ConAbi { abilityValue ::Integer } 
     | IntAbi { abilityValue ::Integer } 
     | WisAbi { abilityValue ::Integer } 
     | ChaAbi { abilityValue ::Integer } 
     deriving (Show)

素敵な事は、ありますそのフィールドへのアクセス。

次は、単純に書くことができます。

setModifier :: Ability -> (Ability, Modifier) 
setModifier abi = (abi, Modifier $ modifier' $ abilityValue abi)

ありフィールドの名前を指定するにおけるいくつかの努力はもちろんですが、これらの値は、「同様の意味論的な意味」を持っている場合、それは通常支払うことになりますあなたは "ゲッター"を導入しています（そして "セッター"のためにレコード記法を使うことができます）。

Answer 2

データ型をリファクタリングすることはできますか？

data Ability = Ability { abilityType :: AbilityType, abilityValue :: Integer } 
data AbilityType = Str | Dec | Con | Int | Wis | Cha 

setModifierは、ウィレム・ヴァン・オンセムと同じ定義を有する。

Answer 3

（小さい依存関係を完全にレンズとしてその正確な同じコードこの回答では、マイクロレンズ・プラットフォームではなく、これらの操作のための）レンズの使用に関するコメント・質問に答える：

{-# LANGUAGE TemplateHaskell #-} 
import Lens.Micro.Platform 
data Ability 
     = StrAbi { _abilityValue :: Integer } 
     | DexAbi { _abilityValue :: Integer } 
     | ConAbi { _abilityValue :: Integer } 
     | IntAbi { _abilityValue :: Integer } 
     | WisAbi { _abilityValue :: Integer } 
     | ChaAbi { _abilityValue :: Integer } 
     deriving (Show) 
makeLenses ''Ability 

-- Just some examples 
getAbilityValue :: Ability -> Integer 
getAbilityValue ab = ab ^. abilityValue 

setAbilityValue :: Ability -> Integer -> Ability 
setAbilityValue ab val = ab & abilityValue .~ val 

modifyAbilityValue :: Ability -> (Integer -> Integer) -> Ability 
modifyAbilityValue ab f = ab & abilityValue %~ f 

-- Edit after reading the question instead of just the comment: 
data Modifier = Modifier Integer deriving (Show) 

setModifier :: Ability -> (Ability, Modifier) 
setModifier ab = (ab,Modifier (ab ^. abilityValue)) 
-- or import Control.Arrow and 
-- setModifier = id &&& Modifier . (^. abilityValue)