どのように文字列化されたバージョンの配列参照をPerlの実際の配列参照に変換できますか？

Question

配列参照の文字列化されたバージョン（ARRAY（0x8152c28））を実際の配列参照に変換する方法はありますか？例

perl -e 'use Data::Dumper; $a = [1,2,3];$b = $a; $a = $a.""; warn Dumper (Then some magic happens);' 

については

が

$VAR1 = [ 
     1, 
     2, 
     3 
    ]; 

Answer 1

はい、（インラインCを使用しなくても）これを行うことができます。例：

use strict; 
use warnings; 

# make a stringified reference 
my $array_ref = [ qw/foo bar baz/ ]; 
my $stringified_ref = "$array_ref"; 

use B; # core module providing introspection facilities 
# extract the hex address 
my ($addr) = $stringified_ref =~ /.*(0x\w+)/; 
# fake up a B object of the correct class for this type of reference 
# and convert it back to a real reference 
my $real_ref = bless(\(0+hex $addr), "B::AV")->object_2svref; 

print join(",", @$real_ref), "\n"; 

ただし、これは実行しません。あなたの実際のオブジェクトが解放されたり再利用された場合は、 がsegfaultsになってしまうかもしれません。

実際に何を達成しようとしていても、確かに良い方法があります。 別の回答へのコメントは、文字列化がハッシュキーとしての参照の使用によるものであることを示しています。それに対応して、より良い方法は、よく戦闘テストされた Tie::RefHashです。

Answer 2

をもたらすであろう最初の質問は：あなたは本当にこれをしたいですか？

その文字列はどこから来ていますか？

あなたのPerlプログラムの外部から来ている場合は、ポインタ値（16進数）は無意味になりますし、それを行う方法はありません。

あなたのプログラムの中から来ている場合は、まずそれを文字列にする必要はありません。

Answer 3

文字列化されたバージョンには配列オブジェクトのメモリアドレスが含まれています。したがって、それを復元できます。このコードは、とにかく（Cygwin、perl 5.8）私のために働きます：

use Inline C; 
@a = (1,2,3,8,12,17); 
$a = \@a . ""; 
print "Stringified array ref is $a\n"; 
($addr) = $a =~ /0x(\w+)/; 
$addr = hex($addr); 
$c = recover_arrayref($addr); 
@c = @$c; 
print join ":", @c; 
__END__ 
__C__ 
AV* recover_arrayref(int av_address) { return (AV*) av_address; } 

$ perl ref-to-av.pl 
Stringified array ref is ARRAY(0x67ead8) 
1:2:3:8:12:17 

Answer 4

私はなぜこれをしたいのか分かりませんが、本当に必要な場合は、トリックを使ってメモリを調べる答えは無視してください。彼らはあなたに問題を引き起こすだけです。

なぜこれをやりたいですか？おそらくより良いデザインがあります。どこからその文字列化された参照を取得していますか？

何らかの理由でそれを行う必要があるとします。

今

use Scalar::Util qw(weaken); 

my $array = [ ... ]; 

$registry{ $array } = $array; 

weaken($registry{ $array }); # doesn't count toward ref count 

、あなたは文字列化フォームを持っている場合、あなただけのハッシュでそれを見て、チェック：まず、ハッシュキーは文字列化形式で、値が弱く参照されたオブジェクトのレジストリを作成しますそれはまだ参照だと確認するために：

if(ref $registry{$string}) { ... } 

またTie::RefHashを試してみて、それがその詳細のすべてを処理させることができます。

これより長い例がIntermediate Perlにあります。

Answer 5

はい、可能です：Devel::FindRefを使用してください。ケース誰かに

use strict; 
use warnings; 
use Data::Dumper; 
use Devel::FindRef; 

sub ref_again { 
    my $str = @_ ? shift : $_; 
    my ($addr) = map hex, ($str =~ /\((.+?)\)/); 
    Devel::FindRef::ptr2ref $addr; 
} 

my $ref = [1, 2, 3]; 
my $str = "$ref"; 
my $ref_again = ref_again($str); 

print Dumper($ref_again); 

Answer 6

は、セグメンテーションフォールトを検出するためのサポートを追加することによって、この便利な、私は拡張していますtobyinkの答えを見つけました。私が発見した2つのアプローチがあります。逆参照の前に、$SIG{SEGV}と$SIG{BUS}をローカルに置き換える最初の方法があります。第2の方法はmasks the child signalで、分岐した子が逆参照できたかどうかを確認します。最初の方法は2番目の方法よりも大幅に高速です。

誰でもこの回答を改善することができます。

最初のアプローチ

sub unstringify_ref($) { 
    use bigint qw(hex); 
    use Devel::FindRef; 

    my $str = @_ ? shift : $_; 
    if (defined $str and $str =~ /\((0x[a-fA-F0-9]+)\)$/) { 
    my $addr = (hex $1)->bstr; 

    local $@; 
    return eval { 
     local $SIG{SEGV} = sub { die }; 
     local $SIG{BUS} = sub { die }; 
     return Devel::FindRef::ptr2ref $addr; 
    }; 
    } 
    return undef; 
} 

私は他の信号が不正なメモリにアクセスしようとする試みに発生する可能性がありますかはわかりません。

第二のアプローチ

sub unstringify_ref($) { 
    use bigint qw(hex); 
    use Devel::FindRef; 
    use Signal::Mask; 

    my $str = @_ ? shift : $_; 
    if (defined $str and $str =~ /\((0x[a-fA-F0-9]+)\)$/) { 
    my $addr = (hex $1)->bstr; 

    local $!; 
    local $?; 
    local $Signal::Mask{CHLD} = 1; 
    if (defined(my $kid = fork)) { 
     # Child -- This might seg fault on invalid address. 
     exit(not Devel::FindRef::ptr2ref $addr) unless $kid; 
     # Parent 
     waitpid $kid, 0; 
     return Devel::FindRef::ptr2ref $addr if $? == 0; 
    } else { 
     warn 'Unable to fork: $!'; 
    } 
    } 
    return undef; 
} 

私はwaitpidの戻り値がチェックする必要があるかはわかりません。