FireMonkeyとオーナー様式のモーダルダイアログセンターを表示

Question

オーナーフォームの中央にモーダルダイアログを表示する際に問題があります。モーダルダイアログを表示する私のコードは：

procedure TfrmMain.btnOpenSettingsClick(Sender: TObject); 
var 
    sdSettingsDialog: TdlgSettings; 

begin 
    sdSettingsDialog := TdlgSettings.Create(Self); 
    sdSettingsDialog.Position := TFormPosition.poOwnerFormCenter; 

    try 
     sdSettingsDialog.ShowModal; 
    finally 
    sdSettingsDialog.Free; 
    end; 
end; 

デザイナーの位置プロパティを変更しようとしましたが、ダイアログを中心にしていないようです。

ここで何が間違っているのか教えてもらえますか？

Answer 1

位置はFireMonkeyではShowModalによって実装されていません。 sdSettingsDialog.UpdateFormPositionをあなたはShowModalを呼び出す前に：あなたが使用することができ、以下のクラスヘルパーで

type 
    TFormHelper = class helper for TForm 
    procedure UpdateFormPosition; 
    end; 

procedure TFormHelper.UpdateFormPosition; 
var 
    RefForm: TCommonCustomForm; 
begin 
    RefForm := nil; 

    case Position of 
    // TFormPosition.poScreenCenter: implemented in FMX.Forms (only one) 
    TFormPosition.poOwnerFormCenter: 
     if Assigned(Owner) and (Owner is TCommonCustomForm) then 
     RefForm := Owner as TCommonCustomForm; 
    TFormPosition.poMainFormCenter: 
     RefForm := Application.MainForm; 
    end; 

    if Assigned(RefForm) then 
    begin 
    SetBounds(
     System.Round((RefForm.Width - Width)/2) + RefForm.Left, 
     System.Round((RefForm.Height - Height)/2) + RefForm.Top, 
     Width, Height); 
    end; 
end;