ExcelのVBAは、シートのダイナミックレンジに渡ってマクロを実行します

Question

最後の質問からの拡張として、私はすべてのワークシートでマクロを実行しようとしています。 ワークシート名をハードコード化できないと言われていますので、現在のソリューションを変更する必要があります。

Sub RemoveCarriageReturns() 
Dim MyRange As Range 
Dim NameList() As Variant 
NameList = Array("OTCUEXTR", "OTFBCUDS", "OTFBCUEL") 
Application.ScreenUpdating = False 
Application.Calculation = xlCalculationManual 

For i = 0 To 2 
    With Worksheets(NameList(i)) 
     For Each MyRange In .UsedRange 
      If 0 < InStr(MyRange, Chr(10)) Then 
       MyRange = Replace(MyRange, Chr(10), "") 
      End If 
     Next MyRange 
    End With 
Next i 

Application.ScreenUpdating = True 
Application.Calculation = xlCalculationAutomatic 
End Sub 

私は、しかし、私は私の限られたVBAの知識が不足しており、ぼんやりとこの見つめて2日後に感じ、私はこだわっている各ワークシートの名前を収集Forループで配列を移入しようとしました、I量と名前が変わる可能性のあるシートの範囲でこのマクロを動作させる方法についてのいくつかの指摘を本当に感謝しています。

あなたがコメントで必要な任意のより多くの情報を提供させていただき

Answer 1

：のみ選択したシートについて元のコードの行に沿ってインデックスを使用することもできます）。

Sub RemoveCarriageReturns() 

Dim MyRange As Range 
Dim ws As Worksheet 

Application.ScreenUpdating = False 
Application.Calculation = xlCalculationManual 

For Each ws In Worksheets 
    With ws 
     For Each MyRange In .UsedRange 
      If 0 < InStr(MyRange, Chr(10)) Then 
       MyRange = Replace(MyRange, Chr(10), "") 
      End If 
     Next MyRange 
    End With 
Next ws 

Application.ScreenUpdating = True 
Application.Calculation = xlCalculationAutomatic 

End Sub 

Answer 2

Public Function GetSheetNames(ByVal wbk As workbook) As String() 
    Dim names() As String 
    Dim count As Integer 
    Dim i As Integer 

     count = wbk.Worksheets.count 

     ReDim names(count - 1) 
     For i = 1 To wbk.Worksheets.count 
      names(i - 1) = wbk.Worksheets(i).Name 
     Next 

     GetSheetNames = names 

    End Function 

使用法：GetSheetNames(Application.ActiveWorkbook)

UPDATE：あなたは（このようにそれを行うことができます

Public Function GetActiveSheetNames(ByVal wbk As workbook) As String() 
Dim names() As String 
Dim count As Integer 
Dim i As Integer 

    count = wbk.Windows(1).SelectedSheets.count 

    ReDim names(count - 1) 
    For i = 1 To wbk.Windows(1).SelectedSheets.count 
     names(i - 1) = wbk.Windows(1).SelectedSheets(i).Name 
    Next 

    GetActiveSheetNames = names 

End Function