カスタムフォーマットのクリップボードデータをTMemoに貼り付けるには？

Question

この質問はthisとそのaccepted answerと一緒にここに投稿されました。

私はWindows APIで快適に感じません。 Topografixによって道EasyGPSを探る

は、クリップボード操作を処理し、私はそれが（GPXは正確には）という名前GPXウィッヒは、実際にプレーンXMLテキストであるカスタムクリップボード形式を使用していることを発見しました。 Clipboard.AsTextの使用は除外されています。

私はこの段階でつまずく：

program ProbeClipboard; 

{$APPTYPE CONSOLE} 

uses 
    SysUtils, 
    Windows, 
    ClipBrd; 

var 
    CF_GPX: Cardinal; 
    ClipboardData: THandle; 

begin 
    CF_GPX:=RegisterClipboardFormat('GPX'); 

    if ClipBoard.HasFormat(CF_GPX) then 
    begin 
    Writeln('GPX format available in clipboard'); 
    // 
    OpenClipboard(0); 

    ClipboardData := GetClipboardData(CF_GPX); 

    if ClipboardData = 0 then 
     raise Exception.Create('Clipboard data Error'); 

    /// How to use GlobalLock and GlobalUnLock 
    /// so that I can paste the Clipboard data 
    /// to a TMemo instance for example 

    CloseClipboard; 
    end; 
end. 

、私はそのプログラムを修正する助けてください。

Answer 1

私はこのように書くと思います：私はCF_GPX形式のテスト外にクリップボードをロッククリップボードOpenコマンドを、移動

program ProbeClipboard; 

{$APPTYPE CONSOLE} 

uses 
    SysUtils, 
    Windows, 
    ClipBrd; 

var 
    CF_GPX: Cardinal; 
    ClipboardData: Windows.HGLOBAL; 
    Ptr: Pointer; 
    Size: DWORD; 

begin 
    CF_GPX := RegisterClipboardFormat('GPX'); 

    Clipboard.Open; 
    try 
    if Clipboard.HasFormat(CF_GPX) then 
    begin 
     Writeln('GPX format available in clipboard'); 

     ClipboardData := Clipboard.GetAsHandle(CF_GPX); 
     if ClipboardData=0 then 
     RaiseLastOSError; 

     Ptr := Windows.GlobalLock(ClipboardData); 
     if Ptr=nil then 
     RaiseLastOSError; 

     try 
     Size := Windows.GlobalSize(ClipboardData); 

     //Ptr now points to a memory block of Size bytes 
     //containing the clipboard data 
     finally 
     Windows.GlobalUnlock(ClipboardData); 
     end; 
    end; 
    finally 
    Clipboard.Close; 
    end; 
end. 

注意を。それはあなたのコードに存在する競合状態を避けるためです。コードでは、HasFormatコールとOpenClipboardコールの間でクリップボードを変更できます。

私はまた、Clipboardクラスを排他的に使用しました。このクラスには必要なだけの機能があり、生のWin32クリップボードAPIを使用する必要はありません。

エラーチェックを入れても！