私のPerlスクリプトで、 "ファイルの記述子が閉じられているファイルハンドルを閉じた状態で" print（）が表示されるのはなぜですか？

Question

私は、このサブルーチンを使ってファイルにログインするperl（リビジョン5.0バージョン8のサブバージョン0）にtcpサーバを持っています。

sub logger { 
     return if ($LOGFILE eq "") ; 
     my ($idt, $str) = @_ ; 
     unless(defined($str)) { 
       $str = $idt ; 
       $idt = '' ; 
     } 
     my ($s,$m,$h,$J,$M,$A) = localtime(time()) ; 
     if(!open(OUT,">>$LOGFILE")) 
     { 
       warn "logger:error open [$LOGFILE]:[$!]\n"; 
       return; 
     } 
     if (!printf OUT "%4.4d/%2.2d/%2.2d %2.2d:%2.2d:%2.2d %s %s -> %s\n", 
         $A+1900, $M+1, $J, $h, $m, $s, $idt, $HOSTNAME, $str) 
     { 
       warn "logger:error print [$LOGFILE]:[$!]\n"; 
       return; 
     } 
     if (!close(OUT)) 
     { 
       warn "logger:error close [$LOGFILE]:[$!]\n"; 
       return; 
     } 
} 

したがって、このログファイルには同時に書き込みが行われます。 例外、私はSTDERRでこのエラーがあります：オープンでエラーなし

printf() on closed filehandle 

logger :error print [/my/path/logFile.LOG]:[Bad File Descriptor]

を！

この問題を解決するにはどうすればよいですか？

Answer 1

OUTは、グローバルパッケージです。

sub logger { 
    $LOGFILE or return; 
    my ($idt, $str) = @_ ; 

    unless(defined($str)) { 
     $str = $idt ; 
     $idt = '' ; 
    } 

    my ($s,$m,$h,$J,$M,$A) = localtime(time()) ; 

    my $OUT; 

    unless (open $OUT, '>>', $LOGFILE) { 
     warn "logger:error open [$LOGFILE]:[$!]\n"; 
     return; 
    } 

    unless (printf $OUT 
     "%4.4d/%2.2d/%2.2d %2.2d:%2.2d:%2.2d %s %s -> %s\n", 
     $A+1900, $M+1, $J, $h, $m, $s, $idt, $HOSTNAME, $str 
    ) { 
     warn "logger:error print [$LOGFILE]:[$!]\n"; 
     return; 
    } 

    unless (close $OUT) { 
     warn "logger:error close [$LOGFILE]:[$!]\n"; 
     return; 
    } 

    return 1; 
}